Rcecode.com

คราวนี้ผมจะพูดถึงการ call (เรียก) function หนึ่ง จะมีผลอย่างไรกับ memory ในส่วน stack และจะมีคำสั่ง assembly อะไรบ้างที่เกี่ยวข้อง

ปกติโปรแกรมจะทำงานเป็นลำดับ โดยมี eip ชี้ไปคำสั่งที่จะถูกประมวลผล แต่เมื่อมีการ call function หนึ่ง eip จะกระโดดไปทำงานใน function ใหม่ และเมื่อทำงานใน function ใหม่จบแล้ว eip จะต้องกระโดดกลับมาทำงานที่ function เดิมต่อ แล้วโปรแกรมรู้ได้อย่างไรละว่า eip ต้องกระโดดกลับไปที่ไหน?

เพื่อให้ eip ชี้ไปที่คำสั่งถัดไปหลังจากกลับมาจาก function ที่เรียก คำสั่งที่ใช้ในการ call function คือ “call” (เช่น “call printf”) จะทำการ “push eip” ลงไปใน stack ก่อน แล้วค่อยกระโดดไปทำงานที่ function ใหม่ และที่จบ function ก็จะมีคำสั่ง “ret” ซึ่งจะเท่ากับ “pop eip” ทำให้โปรแกรมสามารถกลับไปทำงานตามปกติได้ เช่น สมมติว่าโปรแกรมเรา eip ชี้ไปที่ address 0×08112200 และคำสั่งที่ call some_fn ที่ address 0×08112100 และคำสั่งถัดไปคือ address 0×08112205 ผลของการ call ก็จะได้ตามรูปข้างล่าง

note : ไม่มีคำสั่ง assembly ที่แก้ไขค่า หรืออ่านค่า eip โดยตรง ที่เห็นผมเขียน “push eip” และ “pop eip” นั้น เพื่อใช้ในการอธิบายเท่านั้น

แล้วถ้า function มีการส่ง arguments ละ จะเป็นอย่างไร?

วิธีการส่ง arguments จริงๆแล้ว แล้วแต่ compiler ว่าจะใช้ call convention (รูปแบบการเรียก)ไหน แต่ที่ใช้โดยทั่วไป arguments ของแต่ละ function นั้นจะถูก push ลงไปใน stack จาก arguments ตัวหลังสุดไล่ไปยังตัวหน้าสุด ก่อนจะมีการ call function เช่น ใน c เราเขียน some_args(1, 2, 3) เราจะได้ assembly code เป็น (เพื่อเป็นการประหยัดพื้นที่ ดูรูปแรกในห้วข้อ stack frame ข้างล่างนะครับ)

push $3
push $2
push $1
call some_args

note : วิธีส่ง arguments ไม่จำเป็นต้อง push นะครับ แค่ทำให้เหมือนกันก็พอ ซึ่งจะได้เห็นในหัวข้อถัดไป

ส่วน การส่งค่ากลับของ function คนเขียนโปรแกรมคงคุ้นเคยกันอยู่แล้วว่า function ในจะส่งค่ากลับได้เพียงแค่ค่าเดียว ซึ่ง compiler โดยทั่วไปจะส่งกลับผ่านทาง register eax โดยการ set ค่าที่ eax แล้วค่อย ret

function call convention

ในที่นี้ผมจะพูดถึงแค่ 3 แบบเท่านั้นนะครับ โดยทั้ง 3 แบบ arguments จะถูก push จากตัวหลังสุดไปหน้าสุด

c calling convention (cdecl) – เป็นแบบที่ compiler ปัจจุบันใช้ โดย function ที่เรียกจะทำหน้าที่ clear stack เช่นการเรียก some_args(1, 2, 3) จะได้ assembly เป็น

push $3
push $2
push $1
call some_args
add $12,%esp

standard convention (stdcall) – การเรียกแบบนี้ microsoft คิด และใช้ใน dll ของ microsoft เอง ถ้าใครเคยเขียนโปรแกรมโดยใช้ win32 api คงจะเคยเห็น winapi หน้า function ซึ่งถ้าไล่ดูใน header file ของ win32 api ก็จะเห็นว่า define เป็น _stdcall การเรียกแบบนี้ต่างจากแบบแรกคือ function ที่ถูกเรียกจะทำหน้าที่ clear stack โดยใช้คำสั่ง assembly “ret n” เช่นการเรียก some_args(1, 2, 3) จะได้ assembly ของ function ที่เรียกคือ

push $3
push $2
push $1
call some_args

และใน function ที่ถูกเรียกจะจบด้วย assembly

ret $12

fastcall convention (fastcall) – แบบนี้จะคล้ายแบบ “standard convention” ต่างกันตรงที่ argument ตัวแรกจะเก็บไว้ใน ecx และตัวที่สองเก็บไว้ใน edx ส่วนที่เหลือ push ลง stack เหมือนเดิม การเรียกแบบนี้ ผมไม่ยกตัวอย่าง assembly นะครับ เพราะใช้น้อยมาก เมื่อเทียบกับ 2 แบบแรก

note : หลังจากนี้ ถ้าผมพูดถึงการ call function โดยไม่บอกรูปแบบก็ถือว่าเป็น c calling convention

local variables

ในแต่ละ function จะมี local variables ที่ใช้ภายใน function เท่านั้น และเมื่อจบ function พวก local variables จะถูกทำลายอัตโนมัติ

local variables นั้น จะถูกเก็บไว้ใน stack วิธีการจองคือ compiler ทำการคำนวณขนาดของ local variables ทั้งหมด แล้วเพิ่มคำสั่งลบ esp ไว้ที่ตอนเริ่มของ function (อย่าลืมนะครับว่า stack ใน x86 ขยายจาก high address ไป low address) เช่นใน function มีการประกาศตัวแปร “int i; char buf[16];” ได้ขนาด local variables เป็น 20 bytes ซึ่ง compiler จะเพิ่มคำสั่ง

sub $20, %esp

stack frame

ในหัวข้อ assembly ผมได้พูดถึง esp กับ ebp สั้นๆ ในหัวข้อนี้จะได้เห็นว่า register 2 ตัวนี้ถูกใช้งานอย่างไรใน stack

โดย ปกติ ebp ชี้ไปยัง address ของ stack ข้างบน eip ที่ถูก push ลงไปใน stack ก่อนมีการ call function โดยหน้าที่หลักคือ ใช้อ้างอิง function arguments และ local variables ซึ่งเมื่อใช้ ebp การอ้างอิงทั้ง arguments และ local variables นั้นจะไม่มีการเปลี่ยนแปลงตามรูปข้างล่าง โดยสมมติว่ามีการ call function ที่มี 3 arguments และใน function นั้นมีการประกาศตัวแปรไว้เป็น “int i; char buf[8];” (เหมือนตัวอย่างในหัวข้อ “buffer overflow คืออะไร” ใน function main แต่ใช้ i แทน magic)

จากรูปข้างบน อาจจะเรียกทั้งหมดว่า “stack frame” โดยถ้าเราต้องการจะอ้างถึงตัวแปร buf ก็ใช้ ebp-12 ส่วนถ้าต้องการอ้างถึง argument ตัวที่ 1 ก็ใช้ ebp+8 และตัวอื่นๆ ตามรูป

ส่วน “saved eip” ในรูปนั้น ผมได้อธิบายไปในตอนต้นแล้ว มันคือ eip ของคำสั่งที่จะถูกทำงานหลังจากจบ function ที่เรียก

แล้ว “saved ebp” ละมีไว้ทำอะไร เนื่องด้วยเราได้ใช้ ebp เป็น strack frame pointer เพื่อที่จะได้อ้างอิง local variables และ function arguments ได้สะดวก ดังนั้นเมื่อมีการ call function หนึ่ง ebp จะต้องถูกเลื่อนไปที่ stack frame ของ function ที่ถูกเรียก ดังนั้นเราต้องทำเหมือนกับ eip คือเก็บไว้ใน stack เพื่อจะได้เอา (restore) ebp ของ function เดิมกลับมาได้ (ถ้างง ให้อ่านไปก่อนนะครับ จะมีตัวอย่างอีกอัน)

จะเห็นว่าก่อนจะเริ่มทำงานใน function แต่ละครั้งนั้น จะมีการเก็บค่า ebp ย้าย ebp และจองเนื้อที่สำหรับ local variables (ไม่มีการเก็บค่า eip นะครับ อันนี้ถูกรวมอยู่ในคำสั่ง call) และเมื่อจบ function ก็จะมีการ clear stack ที่จองไว้สำหรับ local variables และ restore ebp ก่อนที่จะเรียกคำสั่ง ret

สิ่งที่ต้องทำก่อนเริ่มทำงานใน function จะเรียกว่า function prologue ซึ่งถ้านำตัวอย่างข้างบนมาเขียนเป็น assembly จะเป็น

push %ebp      # เก็บค่า ebp ที่ใช้ใน function ก่อนหน้าไว้ใน stack
mov %esp, %ebp # เลื่อนค่า ebp มาที่ esp (top of stack)
sub $12, %esp  # เลื่อน esp เพื่อจอง memory ให้ local variables

และสิ่งที่ต้องทำก่อนจบ function จะเรียกว่า function epilogue ซึ่งเขียนเป็น assembly ได้เป็น

mov %ebp, %esp # clear memory สำหรับ local variables โดยการย้าย esp มาที่ ebp
pop %ebp       # restore ebp จากค่าที่เก็บไว้ใน stack
ret

เนื่องจากใน x86 มีคำสั่งสำหรับทำ function epilogue คือ leave ซึ่งเท่ากับ mov %ebp,%esp และ pop %ebp ทำให้โดยปกติ เราจะเห็น function epilogue เมื่อเรา disassembly เป็น

leave
ret

บาง คนอาจจะสังเกตเห็น esp ในรูป แล้วสงสัยว่าทำไมถึงไม่ใช้ esp ในการอ้างอิง local variables และ function arguments ละ ในเมื่อ esp ชี้ไปที่ top of stack เสมออยู่แล้ว และก็อยู่ใกล้ local variables กับ function arguments เหตุผลก็คือ

• การ ถ้าใช้ esp ต้องมีการคำนวณทุกครั้ง ที่มีการ push หรือ pop ว่า local variables และ function arguments ห่างจาก esp เท่าไร แต่การใช้ ebp ทำให้การอ้างอิงค่าแต่ละตัวเหมือนเดิมตลอดๆ ไม่ว่า stack จะเปลี่ยนแปลงอย่างไร ทำให้ง่ายต่อการ debug
• เนื่องด้วยต้องคำนวณระยะห่างของ esp ที่กล่าวไปในข้อ 1 ทำให้ compiler ทำงานช้าลง

จริงๆแล้ว compiler เกือบทุกตัว มี option ให้ใช้แต่ esp แล้วเก็บ ebp ไว้ใช้เหมือน register ตัวอื่นๆ เช่นใน gcc จะใช้ -fomit-frame-pointer ส่วนเหตุผลว่า บางครั้งทำไมต้องใช้แบบนี้ ไม่ขอกล่าวในนี้ เดี๋ยวจะยาวเกิน

ก่อนจะจบ ผมขอยกตัวอย่าง ที่มาจากการ compile จริงๆ และจะได้ฝึก assembly ไปด้วย โดยมีโปรแกรมที่เขียนด้วยภาษา c ดังนี้ (ex_04_1.c)

int fn_second(int n1, int n2, char *s)
{
  char bb[16];
  return 1;
}
 
void fn_first(int num)
{
  int i;
  char buf[8];
  fn_second(i, num, buf);
}
 
int main()
{
  fn_first(5);
  return 0;
}

แล้ว compile ด้วย gcc ตามนี้ (ครั้งนี้ ผม compile ให้ใช้วิธี push argument แล้ว call function เพื่อให้เข้าใจง่าย แต่ในหัวข้อถัดไป ผมจะให้ดูอีกรูปแบบหนึ่ง)

$ gcc -march=i586 -fno-pie -fno-stack-protector -z norelro -z execstack 
    -mpreferred-stack-boundary=2 -o call_stack call_stack.c

เมื่อผมทำการ disassembly ออกมาจะได้ (ผมเอามาแสดงแค่ 3 function ที่มีใน c code นะครับ และเป็น address จริงๆ ในเครื่องของผม)

<fn_second>:
# function prologue โดยจองเนื้อที่ขนาด 16 bytes สำหรับ local variable

0x08048394 <+0>:   push   %ebp
0x08048395 <+1>:   mov    %esp,%ebp
0x08048397 <+3>:   sub    $0x10,%esp
0x0804839a <+6>:   mov    $0x1,%eax    # set ค่า 1 ที่จะ return ใน eax
# function epilogue
0x0804839f <+11>:  leave
0x080483a0 <+12>:  ret

<fn_first>:
# function prologue โดยจองเนื้อที่ขนาด 12 bytes สำหรับ local variable

0x080483a1 <+0>:   push   %ebp
0x080483a2 <+1>:   mov    %esp,%ebp
0x080483a4 <+3>:   sub    $0xc,%esp
0x080483a7 <+6>:   lea    -0xc(%ebp),%eax # load address ของ buf ไว้ที่ eax
0x080483aa <+9>:   push   %eax            # push address ของ buf (argument ตัวที่ 3)
0x080483ab <+10>:  pushl  0x8(%ebp)       # push ค่า num (argument ตัวที่ 2)
0x080483ae <+13>:  pushl  -0x4(%ebp)      # push ค่า i (argument ตัวที่ 1)
0x080483b1 <+16>:  call   0x8048394 <fn_second>
0x080483b6 <+21>:  add    $0xc,%esp       # clear arguments ที่ส่งผ่านใน stack
# function epilogue
0x080483b9 <+24>:  leave
0x080483ba <+25>:  ret

<main>:
# function prologue มี 2 คำสั่งเพราะ ไม่มี local variables

0x080483bb <+0>:   push   %ebp
0x080483bc <+1>:   mov    %esp,%ebp
0x080483be <+3>:   push   $0x5       # push argument ตัวที่ 1
0x080483c0 <+5>:   call   0x80483a1 <fn_first>
0x080483c5 <+10>:  add    $0x4,%esp  # clear arguments ที่ส่งผ่านใน stack
0x080483c8 <+13>:  mov    $0x0,%eax  # set ค่า 0 ที่จะ return ใน eax
# function epilogue
0x080483cd <+18>:  leave
0x080483ce <+19>:  ret

ถ้าใครอ่าน assembly code แล้วไม่เห็นภาพ ผมก็มีรูปให้ดู (หวังว่าคนที่ยังไม่เข้าใจ ดูแล้วจะเข้าใจ) โดยผมจะเริ่มคำสั่งจากใน main ที่ address 0x080483be และจบที่ address 0x080483c5 โดย ebp และ esp ชี้ไปที่ address 0xbffff728 อยู่ (address จริงในเครื่องผม) และเนื่องด้วยถ้าทำเป็น step ทั้งหมดรูปจะใหญ่มาก ผมขอไม่เข้าไปใน “call fn_second” และคำสั่งที่ address 0x080483c5 ผมไม่แสดง โดยผลลัพธ์จะเหมือนขั้นตอนแรก

ถ้าใครไม่เคยรู้เรื่องนี้มาก่อน ให้ค่อยๆ ไล่นะครับ ใช้เวลานานหน่อยไม่ต้องรีบร้อนเรื่องนี้สำคัญมากๆ

สุดท้ายให้ลองกลับไปดูในหัวข้อ “buffer overflow คืออะไร” แล้วคิดดูว่าเกิดอะไรขึ้นใน stack ในแต่ละ input ที่เราลองกัน แล้วผมจะอธิบายในหัวข้อถัดไป พร้อมกับการใช้ gdb เบื้องต้น

credit : sleepya [ http://thtutz.blogspot.com ]